Shader "Unlit/AlphaTest"
{
    Properties
    {
        //主要就是将单张纹理Shader和BlinnPhong模型逐片元模型的结合
        //纹理贴图
        _MainTex("MainTex",2D)=""{}
        //漫反射颜色
        _MainColor("MainColor",Color)=(1,1,1,1)
        //高光反射颜色
        _SpecularColor("SpecularColor",Color)=(1,1,1,1)
        //光泽度
        _SpecularNum("SpecularNum",Range(0,20))=15

        //透明度测试用的阈值
        _Cutoff("Cutoff",Range(0,1)) = 0
    }
    SubShader
    {
        //设置渲染队列 决定对象在何时渲染
        Tags{"Queue" = "AlphaTest" "IngnoreProject"="Ture" "RenderType" = "TransparentCutout"}
        Pass
        {
            //设置光照模式
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            //引用内置文件
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            //纹理贴图的映射成员
            sampler2D _MainTex;
            float4 _MainTex_ST;
            //漫反射颜色、高光反射颜色、光泽度
            fixed4 _MainColor;
            fixed4 _SpecularColor;
            float _SpecularNum;
            //透明度测试用的阈值
            fixed _Cutoff;
            struct v2f
            {
                //裁剪空间下的顶点坐标
                float4 pos:POSITION;
                //UV坐标
                float2 uv:TEXCOORD0;
                //世界空间下的法线
                float3 wNormal:NORMAL;
                //世界空间下的顶点坐标
                float3 wPos:TEXCOORD1;

            };
            v2f vert (appdata_base v)
            {
                v2f data;
                //将模型的顶点坐标转换到裁剪空间下
                data.pos = UnityObjectToClipPos(v.vertex);
                //uv坐标计算
                data.uv = v.texcoord.xy *_MainTex_ST.xy + _MainTex_ST.zw;
                //世界空间下的法线
                data.wNormal = UnityObjectToWorldNormal(v.normal);
                //世界空间下的顶点坐标
                data.wPos = mul(UNITY_MATRIX_M,v.vertex);
                return data;
            }

            fixed4 frag (v2f i) : SV_Target
            {

                //颜色纹理的颜色信息
                fixed4 texColor = tex2D(_MainTex,i.uv);
                //判断贴图的 颜色信息中的透明通道 有没有小于阈值
                //如果小于 就直接丢弃
                clip(texColor.a-_Cutoff);
                /* if(texColor.a<_Cutoff)
                    discard; */
                //纹理颜色需要和漫反射材质颜色叠加（乘法）
                fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _MainColor.rgb;
                //光的方向(指向光源方向)
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
                //兰伯特漫反射颜色 = 光的颜色 * 漫反射颜色 * max（0，dot（光的方向，世界坐标下的法线））
                fixed3 lambertColor = _LightColor0.rgb * albedo.rgb *max(0,dot(i.wNormal,lightDir));
                //高光反射颜色
                // 视角方向
                /*
                //方法一：
                float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.wPos);
                */
                //方法二：
                float3 viewDir = normalize(UnityWorldSpaceViewDir(i.wPos));
                //半角向量 = 标准化后的视角方向 + 光的方向
                float3 halfA = normalize(viewDir + lightDir);
                //高光反射颜色 = 光的颜色 * 高光反射颜色 * pow（max（0，dot（世界坐标系下的法线，半角方向），光泽度））
                fixed3 specularColor = _LightColor0.rgb * _SpecularColor * pow(max(0,dot(i.wNormal,halfA)),_SpecularNum);
                //bliinPongColor = 环境光颜色 + 兰伯特漫反射颜色 + 高光反射颜色
                fixed3 color = UNITY_LIGHTMODEL_AMBIENT.rgb * albedo.rgb + lambertColor + specularColor;
                return fixed4(color.rgb,1);


            }
            ENDCG
        }
    }
}