Properties
    {
        //材质的漫反射颜色
        _MainColor("MainColor",Color) = (1,1,1,1)
    }
    SubShader
    {
        //书写光照的 逻辑，一般都要设置光照模式
        //设置光照模式 Forward这种模式 主要是用来处理 不透明物体的 关照渲染
        Tags { "LightMode"="ForwardBase" }
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            //材质的漫反射颜色
            fixed4 _MainColor;
            //顶点着色器传递给片元着色器的内容
            struct v2f
            {
                //裁剪空间下的顶点坐标信息
                float4 pos:SV_POSITION;
                //对应顶点的漫反射反射光照颜色
                fixed3 color:COLOR;
            };
            //逐顶点光照，所以相关的逻辑 需要书写在顶点着色器回调函数中
            v2f vert (appdata_base v)
            {
                v2f v2fData;
                //将模型空间下的 顶点转换到裁剪空间下
                v2fData.pos = UnityObjectToClipPos(v.vertex);
                //公式：漫反射光照颜色 = 光源颜色 * 材质的漫反射颜色 * max（0，标准化后物体表面的法向量 · 标准化后的光源方向向量）
                //光照颜色 _LightColor0
                //模型表面的法线的向量 v.normal
                //获取 相对于世界坐标下的 法线信息
                float3 normal = UnityObjectToWorldNormal(v.normal);
                //光源方向 _WorldSpaceLightPos0
                //获取 光源方向的单位向量
                float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);

                //参数全部获取 进行计算
                fixed3 color = _LightColor0.rgb * _MainColor *  max(0,dot(normal,lightDir));
                //加上兰伯特光照模型的 环境光变量的目的是 希望阴影处不要全黑 不然 看起来有一些不自然
                //目的是为了让表现 效果更接近于真实
                v2fData.color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;

                return v2fData;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //只要 把计算好的兰伯特关照颜色 传递出去就好了
                return fixed4(i.color.rgb,1);
            }
            ENDCG
        }
    }

Properties
{
    _MainColor("MainColor",Color) = (1,1,1,1)
}
SubShader
{
    Tags { "LightMode"="ForwardBase" }
    Pass
    {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"
        #include "Lighting.cginc"
        float3  _MainColor;
        //顶点着色器返回出去的内容
        struct v2f
        {
            //裁剪空间下的顶点位置
            float4 pos:SV_POSITION;
            //世界空间下的法线位置
            float3 normal:NORMAL;
        };
        //注意 顶点着色器回调函数
        //最主要的作用
        //是 处理顶点、法线、切线的等坐标数据转换
        v2f vert (appdata_base v)
        {
            v2f v2fData;
            //转换 模型空间下的顶点 到 裁剪空间中
            v2fData.pos =UnityObjectToClipPos(v.vertex);
            //转换 模型空间下的法线 到 裁剪空间中
            v2fData.normal = UnityObjectToWorldNormal(v.normal);
            return v2fData;
        }

        fixed4 frag (v2f i) : SV_Target
        {
            //得到光源的单位向量
            float3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
            fixed3 color = _MainColor.rgb * _LightColor0.rgb * max(0,dot(lightDir,i.normal));
            //加上兰伯特光照模型的 环境光变量的目的是 希望阴影处不要全黑 不然 看起来有一些不自然
            //目的是为了让表现 效果更接近于真实
            color = UNITY_LIGHTMODEL_AMBIENT.rgb + color;
            return fixed4(color.rgb,1);
        }
        ENDCG
    }
}