Shader "Unlit/FrameAnimation"
{
    Properties
    {
        _MainTex("Texture", 2D) = "white" {}
        //图集的行列
        _Rows("Rows",int) = 8
        _Columns("Columns",int) = 8
        //切换动画速度的变量
        _Speed("Speed",float) = 1.0
    }
    SubShader
    {
        //设置透明Shader
        Tags { "RenderType"="Trasparent" "Queue" = "Transparent" "IngnoreProjector" = "True" }
    
        Pass
        {
            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
            

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };
            //属性映射
            sampler2D _MainTex;
            int _Rows;
            int _Columns;
            float _Speed;
            v2f vert (appdata_base v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.texcoord;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //得到当前帧 利用时间变量计算
                float frameIndex = floor(_Time.y * _Speed) % (_Rows*_Columns);
                //计算小图片 采样时的起始位置计算(列，行)
                //除以对应的行列 目的是将行列值 转换为 0-1 范围内
                //1 - (floor(frameIndex / _Columns) + 1) / _Rows
                //+1 的目的是把格子左上角转化为格子的左下角
                //1- 的目的是UV坐标的采样是从左下角开始
                float2 frameUV = float2(frameIndex % _Columns / _Columns , 1 - (floor(frameIndex / _Columns) + 1) / _Rows);
                //得到UV缩放比例 相当于从0-1的大图 映射到0~1/n的小图
                float2 size = float2(1.0 / _Columns , 1.0 / _Rows);
                //计算最终的UV坐标采样信息
                //乘以size 相当于把0~1范围 缩放到了 0~1/n范围内
                //再加上frameUV 相当于把采样的起始位置 移动到了对应的小格子的起始位置
                float2 uv = i.uv * size + frameUV;
                return tex2D(_MainTex, uv);
            }
            ENDCG
        }
    }
}