Shader "Unlit/2DWater"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Color ("Color", Color) = (1,1,1,1)
        //波动幅度
        _WaveAmplitude ("WaveAmplitude", Float) = 1
        //波动频率
        _WaveFrequency ("WaveFrequency", Float) = 1
        //波长的倒数
        _InWaveLength ("InWaveLength", Float) = 1
        //纹理变化速度
        _Speed ("Speed", Float) = 1
    }
    SubShader
    {
        //透明Shader渲染相关渲染标签 + 关闭批处理
        Tags { "RenderType"="Transparent" "Queue" = "Transparent" "IgnoreProjector" = "True" "DisableBatching" = "false"}

        Pass
        {
            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha
            Cull Off
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            
            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _Color;
            float _WaveAmplitude;
            float _WaveFrequency;
            float _InWaveLength;
            float _Speed;
            v2f vert (appdata_base v)
            {
                v2f o;
                //模型空间下的偏移位置
                float4 offset;
                //这里使用的2D流水模型 上下是x轴，左右是z轴 前后是y轴
                //这里让它进在模型空间下的x进行偏移
                offset.x = sin(_Time.y * _WaveFrequency + v.vertex.z * _InWaveLength) * _WaveAmplitude;
                offset.yzw = float3(0,0,0);
                o.vertex = UnityObjectToClipPos(v.vertex + offset);
                //o.uv = v.texcoord * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv = TRANSFORM_UV(v.texcoord);
                //结合纹理变化
                o.uv += float2(0,_Time.y * _Speed);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 color = tex2D(_MainTex, i.uv);
                color.rgb *= _Color.rgb;
                return color;
            }
            ENDCG
        }
    }
}

Shader "Unlit/Billboarding"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Color("Color", Color) = (1,1,1,1)
        //用于控制垂直广告牌和全向广告牌的变化
        _VerticalBillboarding("VerticalBillboarding", Range(0,1)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" "Queue"="Transparent" "IgnoreProjector"="True" "DisableBatching"="True" }

        Pass
        {
            ZWrite Off
            Blend SrcAlpha OneMinusSrcAlpha
            Cull Off

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Color;
            float _VerticalBillboarding;

            v2f vert (appdata_base v)
            {
                v2f o;
                //新坐标系的中心点（默认我们使用的还是模型空间点的原点）
                float3 center = float3(0,0,0);
                //计算Z轴的方向
                float3 cameraInObjectPos = mul(unity_WorldToObject, float4(_WorldSpaceCameraPos, 1));
                //得到Z轴对应的向量
                float3 normalDir = cameraInObjectPos - center;
                //相当于把y轴往下压 如果_VerticalBillboarding=0 就代表我们把y轴压到了xz平面上 如果是1 就是正常的全方向的广告牌
                normalDir.y *= _VerticalBillboarding;
                //单位化Z轴的向量
                normalDir = normalize(normalDir);
                //模型空间下的Y轴正方向 作为它的oldUp
                //为了避免Z轴和010重合，因为重合后叉乘 会得到零向量
                float3 upDir = normalDir.y > 0.999 ? float3(0,0,1) : float3(0,1,0);
                //利用叉乘计算X轴的方向
                float3 rightDir = normalize(cross(upDir, normalDir));
                //计算我们的Y轴 也就是newUp
                upDir = normalize(cross(normalDir, rightDir));
                //得到顶点相对于新坐标系中心点的偏移量
                float3 centerOffset = v.vertex.xyz - center;
                //利用三个轴向进行最终的顶点计算
                float3 newVertexPos = center + rightDir * centerOffset.x + upDir * centerOffset.y + normalDir * centerOffset.z;
                //把新的顶点转换到裁剪空间中
                o.vertex = UnityObjectToClipPos(float4(newVertexPos, 1));
                //计算UV坐标
                o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //对纹理采样
                float4 color = tex2D(_MainTex, i.uv);
                color.rgb *= _Color.rgb;
                return color;
            }
            ENDCG
        }
    }
}

void Start()
{
    MeshFilter meshFilter = GetComponent<MeshFliter>();
    if(meshFilter != null)
    {
         Mesh mesh = meshFilter.mesh;
         Vector3[] = vertices = mesh.vertices;
         Color[] colors = new Color[vertices.Length];
         for(int i = 0; i < vertices.Length; i++)
         {
             //将模型空间存储到颜色中
             color[i] = new Color(vertices.x,vertices.y,vertices.z,1);     
         }
    }
    mesh.colors = colors;
}

Shader "Unlit/2DWaterShadow"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Color ("Color", Color) = (1,1,1,1)
        //波动幅度
        _WaveAmplitude ("WaveAmplitude", Float) = 1
        //波动频率
        _WaveFrequency ("WaveFrequency", Float) = 1
        //波长的倒数
        _InWaveLength ("InWaveLength", Float) = 1
        //纹理变化速度
        _Speed ("Speed", Float) = 1
    }
    SubShader
    {
        //透明Shader渲染相关渲染标签 + 关闭批处理
        Tags { "RenderType"="Transparent" "Queue" = "Transparent" "IgnoreProjector" = "True" "DisableBatching" = "false"}
        //实现顶点动画的Pass
        Pass
        {
            //此处省略
        }
        //该Pass主要是用于进行阴影投影 主要是用来计算阴影映射投影的
        Pass
        {
            Tags{"LightMode" = "ShadowCaster"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            //该编译指令是告诉Unity编译器生成多个着色器变体
            //用于支持不同类型的阴影（SM，SSM等）
            //可以确保着色器能够在所有可能的阴影投射模式下正确渲染
            #pragma multi_compile_shadowcaster

            //这个内置文件包含了关键的阴影计算相关的宏
            #include "UnityCG.cginc"

            struct v2f
            {
                //顶点到片元着色器 阴影投影结构体的数据宏
                //这个宏定义了一些标准的成员变量，用于在阴影投射路径中传递顶点数据到片元着色器
                V2F_SHADOW_CASTER;
            };

            float _WaveAmplitude;
            float _WaveFrequency;
            float _InWaveLength;
            
            v2f vert(appdata_base v)
            {
                v2f data;
                //模型空间下的偏移位置
                float4 offset;
                //这里使用的2D流水模型 上下是x轴，左右是z轴 前后是y轴
                //这里让它进在模型空间下的x进行偏移
                offset.x = sin(_Time.y * _WaveFrequency + v.vertex.z * _InWaveLength) * _WaveAmplitude;
                offset.yzw = float3(0,0,0);
                //进行模型空间下的顶点偏移 直接在模型空间下进行计算
                v.vertex = v.vertex + offset;
                //转移阴影投射器法线偏移宏
                //用于在顶点着色器中计算和传递投影所需的变量
                //主要做了
                //1. 将对象空间的顶点位置转化到裁剪空间
                //2. 考虑法线偏移，以减轻阴影失帧问题，尤其是在处理自阴影时
                //3. 传递顶点的投影空间位置，用于后续的阴影计算
                TRANSFER_SHADOW_CASTER_NORMALOFFSET(data);
                return data;
            }

            float4 frag(v2f i):SV_TARGET
            {
                //阴影投射片元宏
                //将深度值写入到阴影映射纹理中
                //我们主要在片元着色器中使用
                SHADOW_CASTER_FRAGMENT(i);
            }
            ENDCG
        }
    }
}